package {
	import flash.display.*;
	import flash.events.*;
	
	public class MatchingGame5 extends MovieClip {
		// game constants
		private static const boardWidth:uint = 6;
		private static const boardHeight:uint = 6;
		private static const cardHorizontalSpacing:Number = 52;
		private static const cardVerticalSpacing:Number = 52;
		private static const boardOffsetX:Number = 120;
		private static const boardOffsetY:Number = 45;

		private var firstCard:Card;
		private var secondCard:Card;
		
		public function MatchingGame5():void {
			// make a list of card numbers
			var cardlist:Array = new Array();
			for(var i:uint=0;i<boardWidth*boardHeight/2;i++) {
				cardlist.push(i);
				cardlist.push(i);
			}
			
			// create all the cards, position them, and assign a randomcard face to each
			for(var x:uint=0;x<boardWidth;x++) { // horizontal
				for(var y:uint=0;y<boardHeight;y++) { // vertical
					var c:Card = new Card(); // copy the movie clip
					c.stop(); // stop on first frame
					c.x = x*cardHorizontalSpacing+boardOffsetX; // set position
					c.y = y*cardVerticalSpacing+boardOffsetY;
					var r:uint = Math.floor(Math.random()*cardlist.length); // get a random face
					c.cardface = cardlist[r]; // assign face to card
					cardlist.splice(r,1); // remove face from list
					c.addEventListener(MouseEvent.CLICK,clickCard); // have it listen for clicks
					addChild(c); // show the card
				}
			}
		}
		
		// player clicked on a card
		public function clickCard(event:MouseEvent) {
			var thisCard:Card = (event.target as Card); // what card?
			
			if (firstCard == null) { // first card in a pair
				firstCard = thisCard; // note it
				firstCard.gotoAndStop(thisCard.cardface+2); // turn it over
				
			} else if (firstCard == thisCard) { // clicked first card again
				firstCard.gotoAndStop(1); // turn back over
				firstCard = null;
				
			} else if (secondCard == null) { // second card in a pair
				secondCard = thisCard; // note it
				secondCard.gotoAndStop(thisCard.cardface+2); // turn it over
				
				// compare two cards
				if (firstCard.cardface == secondCard.cardface) {
					// remove a match
					removeChild(firstCard);
					removeChild(secondCard);
					// reset selection
					firstCard = null;
					secondCard = null;
				}
				
			} else { // starting to pick another pair
				// reset previous pair
				firstCard.gotoAndStop(1);
				secondCard.gotoAndStop(1);
				secondCard = null;
				// select first card in next pair
				firstCard = thisCard;
				firstCard.gotoAndStop(thisCard.cardface+2);
			}
		}
		
	}
}